SPARQL-søk

SPARQL lar deg hente ut metadata om datasett i Transportportal.no programmatisk.

Endepunktet dekker hele Felles datakatalog. For å begrense resultatet til Transportportal må du filtrere på egenskapen fdk:isRelatedToTransportportal.

Verktøy

• SPARQL-sandkasse – interaktivt grensesnitt for å teste spørringer
• W3C sin SPARQL-dokumentasjon.

Hente transportportal-datasett

Denne spørringen henter datasett som er knyttet til Transportportal.no:

Kopier
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX fdk: <https://raw.githubusercontent.com/Informasjonsforvaltning/fdk-reasoning-service/main/src/main/resources/ontology/fdk.owl#>

SELECT ?dataset ?title
WHERE {
  ?dataset a dcat:Dataset .
  ?dataset fdk:isRelatedToTransportportal true .
  ?dataset dct:title ?title .
}
LIMIT 20

Filtrere på utgiver

Finn transportportal-datasett fra en bestemt virksomhet (her ved å søke i utgivernavn):

Kopier
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX fdk: <https://raw.githubusercontent.com/Informasjonsforvaltning/fdk-reasoning-service/main/src/main/resources/ontology/fdk.owl#>

SELECT ?dataset ?title ?publisherName
WHERE {
  ?dataset a dcat:Dataset .
  ?dataset fdk:isRelatedToTransportportal true .
  ?dataset dct:title ?title .
  ?dataset dct:publisher ?publisher .
  ?publisher foaf:name ?publisherName .
  FILTER(CONTAINS(LCASE(?publisherName), "vegvesen"))
}
LIMIT 20

Filtrere på beskrivelse

Søk etter transportportal-datasett der beskrivelsen inneholder et bestemt ord:

Kopier
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX fdk: <https://raw.githubusercontent.com/Informasjonsforvaltning/fdk-reasoning-service/main/src/main/resources/ontology/fdk.owl#>

SELECT ?dataset ?description
WHERE {
  ?dataset a dcat:Dataset .
  ?dataset fdk:isRelatedToTransportportal true .
  ?dataset dct:description ?description .
  FILTER(CONTAINS(LCASE(?description), "rutetider"))
}
LIMIT 20